Функція Mouse.move()

Документація

Mouse.move()


Переміщує курсор на підключеному комп’ютері. Рух на екрані завжди пов’язаний з поточним положенням курсора. Слід викликати Mouse.begin() перед використанням Mouse.move().
Застереження: коли Ви використовуєте команду Mouse.move(), Arduino бере контроль над мишею. Переконайтеся, що Ви маєте контроль, перед використанням цієї команди. Кнопка для перемикання стану управління миші є дієвою.

Синтаксис
Mouse.move(xVal, yPos, wheel)

Параметри
xVal: обсяг руху по осі x — signed char
yVal: обсяг руху по осі y — signed char
wheel: обсяг руху колеса прокрутки — signed char

Повертає
нічого

Приклад
const int xAxis = A1;         // аналоговий датчик для осі X  
const int yAxis = A2;         // аналоговий датчик для осі Y

int range = 12;               // вихідний діапазон руху X чи Y
int responseDelay = 2;       // затримка відгуку миші, у мс 
int threshold = range/4;      // поріг відпочинку
int center = range/2;         // відстань від позиції
int minima[] = { 
  1023, 1023};                // фактичний мінімум analogRead для {x, y}
int maxima[] = {
  0,0};                       // фактичний максисмум analogRead для {x, y}
int axis[] = {
  xAxis, yAxis};              // номери пінів для {x, y}
int mouseReading[2];          // фінальні зчитування миші для {x, y}


void setup() {
 Mouse.begin();
}

void loop() {

// зчитати і масштабувати дві осі:
  int xReading = readAxis(0);
  int yReading = readAxis(1);

// рух миші:
    Mouse.move(xReading, yReading, 0);
    delay(responseDelay);
}

/*
  зчитує осі (0 або 1 для x або y) та масштабує
  діапазон вхідних значень до діапазону від 0 до <діапазон>
*/

int readAxis(int axisNumber) {
  int distance = 0;    // відстань між центром та вихідним діапазоном

  // зчитати аналоговий вхід:
  int reading = analogRead(axis[axisNumber]);

// поточне значення перевищує максимум або мінімум для цієї осі,
// перевстановити max чи min:
  if (reading < minima[axisNumber]) {
    minima[axisNumber] = reading;
  }
  if (reading > maxima[axisNumber]) {
    maxima[axisNumber] = reading;
  }

  // зіставити значення з діапазону  аналогового входу у вихідний діапазон:
  reading = map(reading, minima[axisNumber], maxima[axisNumber], 0, range);

 // якщо вихідне значення поза порогом відпочинку, то:
  if (abs(reading - center) > threshold) {
    distance = (reading - center);
  } 

  // вісь Y має бути інвертована, щоб правильно відобразити рухи
  if (axisNumber == 1) {
    distance = -distance;
  }

  // повертає відстань для цієї осі:
  return distance;
}

Повернутись до головної

Коментарі 0

Тільки зареєстровані та авторизовані користувачі можуть залишати коментарі.