Функція get()

EEPROM

get()

Зчитує будь-який тип даних чи об’єкт з EEPROM.

Синтаксис

EEPROM.get(адреса, дані)

Параметри

адреса: місце, з якого зчитувати, починаючи з 0 (int)
дані: дані, які зчитувати, можуть бути первісного типу (наприклад, float) чи індивідуальної структури

Повертає

Посилання на дані, що передаються

Приклад

#include <EEPROM.h>

struct MyObject{
  float field1;
  byte field2;
  char name[10];
};

void setup(){

  float f = 0.00f;   // змінна для зберігання даних, зчитаних з EEPROM.
  int eeAddress = 0; // адреса EEPROM для початку зчитування
  Serial.begin( 9600 );
  while (!Serial) {
    ; // почекати на з’єднання послідовного порту. Лише для Leonardo
  }
  Serial.print( "Зчитати float з EEPROM: " );

  // Отримати дані float з EEPROM на позиції 'eeAddress'
  EEPROM.get( eeAddress, f );
  Serial.println( f, 3 );  // Може надрукувати 'ovf, nan', якщо дані всередині EEPROM не є дійсним float.

  // get() може використовуватися з індивідуальними структурами теж. 
  eeAddress = sizeof(float); // перемістити адресу до наступного байта після float 'f'.
  MyObject customVar; // змінна для зберігання спеціального об’єкта, зчитаного з EEPROM.
  EEPROM.get( eeAddress, customVar );

  Serial.println( "Зчитати спеціальний об’єкт з EEPROM: " );
  Serial.println( customVar.field1 );
  Serial.println( customVar.field2 );
  Serial.println( customVar.name );
}

void loop(){ /* Порожній цикл */ }

Повернутись до головної