Функція beginSMS()

Клас GSM_SMS

beginSMS()

Визначає номер телефону для відправки SMS-повідомлення.

Синтаксис

SMS.beginSMS(номер)

Параметри

номер: масив символів, номер телефону, на який відправити SMS

Повертає

int
В асинхронному режимі beginSMS() повертає 0, якщо остання команда досі виконується, 1, якщо успіх, >1 у разі помилки. У синхронному режимі повертає 1, якщо успішно виконано, 0, якщо ні.

Приклад

#include <GSM.h>

#define PINNUMBER ""

// ініціалізувати приклад бібліотеки
GSM gsmAccess; // включити параметр істини для активації налагодження
GSM_SMS sms;

void setup()
{
  // ініціалізувати послідовні зв’язки
  Serial.begin(9600);

  Serial.println("Відправник SMS-повідомлень");

  // стан підключення
  boolean notConnected = true;

     // Розпочати роботу GSM-шилда
  // Якщо SIM має PIN, передайте його як параметр begin () у лапках
  while(notConnected)
  {
    if(gsmAccess.begin(PINNUMBER)==GSM_READY)
      notConnected = false;
    else
    {
      Serial.println("Не підключено");
      delay(1000);
    }
  }

  Serial.println("GSM ініціалізовано");
}

void loop()
{

  Serial.print("Ввести мобільний номер: ");
  char remoteNumber[20];  // телефонний номер для відправки sms
  readSerial(remoteNumber);
  Serial.println(remoteNumber);

  // текст sms
  Serial.print("Тепер ввести вміст SMS: ");
  char txtMsg[200];
  readSerial(txtMsg);
  Serial.println("Відправка");
  Serial.println();
  Serial.println("Повідомлення:");
  Serial.println(txtMsg);

  // Відправити повідомлення 
  sms.beginSMS(remoteNumber);
  sms.print(txtMsg);
  sms.endSMS(); 
  Serial.println("\nЗавершено\n");
}

/*
  Зчитати послідовний ввід
 */
int readSerial(char result[])
{
  int i = 0;
  while(1)
  {
    while (Serial.available() > 0)
    {
      char inChar = Serial.read();
      if (inChar == '\n')
      {
        result[i] = '\0';
        Serial.flush();
        return 0;
      }
      if(inChar!='\r')
      {
        result[i] = inChar;
        i++;
      }
    }
  }
}

Повернутись до головної